
1. Preface

This document contains development and coding guidelines for application and component development that is done with Microsoft Visual Basic 5.0 or later. The document contains information that is specific for Visual Basic language and not directly applicable to other programming environments. 

All guidelines that are common to all programming environments are located in “Programming standard for Windows software development” document that forms the base of all information in this document. In this document chapters 2-5 have the same paragraph numbering as the common standard paper so it is easy to look up information from either of these documents based on other.

NOTE! 
Conventions and guidelines that are outlined in this document and all environment specific additional parts must be followed during all program development phases - even when just creating a quick demo or testbench since this new code may (and will very likely) be needed in “real” projects too!

1.1 Definitions, acronyms and abbreviations

COM
Component Object Model

VB
Visual Basic

VBA
Visual Basic for Applications

1.2 References

This document is partially based on following sources:

	Author
	Title, publisher

	Maguire, Steve
	Writing solid code. Microsoft press 1993.

	McConnell, Steve.
	Code complete. Microsoft press 1993

	The Mandelbrot Set
	Advanced Visual Basic 5, Microsoft Press 1998


True references:

[SDG-Win32]
Windows Software Development Guideline, revision 2, Wallac Oy, J.Sakki

2. Naming conventions

2.1 Variable naming

Since in a Visual Basic program the variable type does not play as important a role as for example in a C program, Hungarian notation is not needed. The exception to this is when calling Windows API or any other DLL calls. The variables that are passed to Windows API calls or any other DLL functions must use Hungarian notation exactly as described in the Wallac Visual C++ programming standard. This helps to avoid errors caused by wrong parameter types, which may lead to serious errors when calling DLL procedures.

Remember that normally in Visual Basic code, VB itself handles parameter type conversions automatically in the background. Sometimes Hungarian notation does make sense in VB code (like when you have both number and string variable for the same data). In this case you can use variable type prefixes also in your VB code but you must use Hungarian notation exactly as described in the Wallac Visual C++ programming standard. In VB following additional types can be used:

	Prefix2
	Type (s)
	Description
	Example

	Str,

Text
	String
	String value. Instead of str Text can also be added after variable name. 
	StrSQL or
SQLText


Following scope prefixes must be used as identifiers of global, module level and static variables. Only local variables are presented without a prefix.

	Scope prefix
	Data Type
	Example

	<NoPrefix>
	Variable is local to method or function.
	UserName

	m_
	Module data
	m_UserName

	g_
	Global data
	g_UserName

	s_
	Static data
	s_UserName


TIP!
Because Visual Basic code is not case-sensitive and the editor corrects the case to the one used in the declaration, it can be used to make sure you typed the variable / class / constant / method / property / etc. name correctly. Since the names will have uppercase letters in them, type them in your code with lowercase letters and see if the case is corrected when you change the line. If not, you didn’t type it correctly.
2.2 Function/method/label naming

All user-defined functions and class methods should be named as stated in the common standard. Currently we do not use any kind of prefix with function name to specify for e.g. scope. Reason for this is to harmonize our VB coding standard with C++ standard where they do not use prefixes as VB programmers have previously used.

In Visual Basic, event handlers are automatically named by the environment and have the form of <ObjectName|ControlName>_<EventName>. 

Private Sub cmdHello_Click()

  MsgBox "Hello World!"

End Sub

Avoid using underscore characters when naming your own procedures to make sure they are not misunderstood to be event handlers.

The following naming of the error handler labels should be used:

Private Function GetHelloText() as String

  On error goto ErrHandler

  ' Real code that does the job goes here

ExitProc:

  ‘ Cleanup code goes here

  exit function

ErrHandler:

  GetHelloText = ""

  resume ExitProc

End Sub

2.3 Project and class naming

All VB projects must be named by the following rules:

· Follow general naming principles outlined in the common standard.

· Consider using 8 character names and no spaces to avoid problems.

If a VB project contains any public classes, its name will be available to all COM clients and must follow these rules:

· All COM servers that belong to the same product must use a common name prefix (like “MlrServ”, MlrRes”, “MlrCtrls”).

· The name must be universally unique so you can not create a module whose name is “Wallac”. That is because the project name is also used as the typelib name which needs to be unique in COM namespace. Due to the same rule you cannot use bare product names as the project name.

· Maximum value for the combined length of the project name and the name of any public class within the project is 39 characters. Use short project names and longer class names if possible, because class names are more frequently referenced within the code than project names. The actual project name can be thought to be just an abbreviation of the real name which is actually stored to the project description.

The project name is used, for example, when registering classes to registry and so e.g., when the project name is “MlrRes” and class name is “AssayResults” the full ProgID (which can be used when object is created with CreateObject() call) for this COM object becomes “MlrRes.AssayResults”.

[image: image2.png]Project] - Project Properties

General | ke | conple | conponent |

P artup Ot
rciver o =] fworn =
i
irees

ProjctHob
o Fie e Comen

RN
Eroject Description;
[Wallac 1420 AssayResult nterfaces 1.0

Threading Hodel

-
[apartment Threaded

7 Upgrade Actvet Controls |

Is e =

o | rews | _ome





Picture 1 - Setting project properties

VB Classes must also follow the general naming principles outlined in the common standard. In addition to this, the following class name prefixes must be used:

	Name prefix
	Description
	Example

	W or <no prefix> 
	Public class which can be instantiated from outside of this module. When using <no prefix> you should avoid overloading commonly used words like Assay by adding for e.g. the project name to the class name
	WProtocolData or 
1420Assay

	C
	Private class module.
	CProtocolData

	I
	Class is just a public COM interface description (used as base class for “Implements”) and all its methods are empty.
	IProtocolData


The previous prefixes make it very easy to write clear and easy to understand code like the one below:

  . . .

  Dim ProtocolData as CprotocolData

  Dim g_Insrument as Winstrument

  Set ProtocolData = New CprotocolData

  Set g_Insrument = New Winstrument

  . . . 

  . . .

  implements IProtocolData

  . . . 

2.4 Control naming

When you CREATE ActiveX controls with VB you must follow the project and naming conventions outlined in the previous chapter of this document. The public control modules are (really) just public classes and must be named accordingly.

When you USE ActiveX controls in your forms you name all standard VB controls with a prefix in the name that tells the control type. A table of the prefixes for the standard controls is presented in Appendix 2 - Control Naming. For the ones not included in this list (or controls you have made yourself), you must use ctl as the name prefix.

3. Code formatting conventions

3.1 Code formatting in general

Purpose of formatting code is to make it clearer to read for you and other developers. The general idea is to format your code in such a way that the program flow is clearly indicated. A uniform way of formatting code makes it much easier for other developers to read and understand the meaning and purpose of your code.

Visual Basic 5 & 6 provide two great ways to aid this task: Templates and Add-Ins. Templates are handy when there are static and standard ways of formatting and commenting your code. Wallac has several templates that can save programmers time when adding new code modules to VB projects.

Note!
This topic is covered in greater depth in common Windows Software Coding Guideline. 

3.2 Common code element formats

If statement format

If statements must be formatted as follows:

If <Expression> Then 

  <Statement1>

Else

  <Statement2>

End If

If <statement > consists of several code blocks; be sure to leave blank lines before and after each code block:

If <Expression> Then 

  ‘ Comment for block 1

  <StatementLine1>

  <StatementLine2>

  <StatementLine2>

  ‘ Comment for block 2

  <StatementLine1>

  <StatementLine2>

  <StatementLine2>

End If

Even if the “else” part of the if statement is missing you must still put Statement1 on a separate line after Expression as shown in the next example:

If <Expression> Then

  <Statement1>

End If

Examples of properly formatted IF statements:

If a < b Then

  MsgBox “A is smaller than B”

End If

If (VB > VC) and (DCOM > COM) and (Internet is Nothing) then

  MsgBox “Something weird has happened, please call 911”

End if 

If ((VB > VC) and (DCOM > COM)) or _

   (Internet is Nothing) Then

  MsgBox “Something weird has happened, please call 911”

End if 

Select-Case statement format

Select-Case statements must be formatted as follows:

Select Case AssayId

  Case xxx

    'Prenatal assay

    code begins here

  Case yyy

    'Neonatal assay

    code begins here

End Select

Do-Loop statement format

Do-Loop statements must be formatted as follows:

Do <Until or While statement>

  <Statement1.1>

  <Statement1.2>

Loop 

Or

Do 

  <Statement1.1>

  <Statement1.2>

Loop <Until or While statement>

Always use do-loop instead of while-wend.

3.3 Basic function/method implementation format

Function and method implementations should be formatted according to the following sample:

Function HoursToWeekend(ByVal DateToCountFrom As Date) As Long

‘

‘ Here is a comment that tells briefly WHAT the function does

‘ See the commenting section of this document for more information!

‘ remember to explain the parameter(s) and possible return value.

‘

  Dim Days As Long

  Dim Hours As Long

  Dim DateOnFriday As Date

  ‘ The actual function code goes here

  Days = vbFriday - WeekDay(DateToCountFrom)

  If Days > 0 Then

    DateOnFriday = DateAdd(“d”, Days, DateToCountFrom)

    Hours = DatePart(“h”, DateToCountFrom)

    Hours = Hours + DateDiff(“h”, DateToCountFrom, DateOnFriday)

  Else

    Hours = 0

  EndIf

  ‘ You should set the return value from a local variable in the end of function

  HoursToWeekend = Hours

End Function

Note! 
Remember always to specify explicitly your arguments to be passed either ByVal or ByRef. This is important since the default behavior has changed in the past and it is not always clear which way is the programmers’ real intention.

The line continuation character must be used as follows when creating one logical code line that is longer than one physical line:

. . . 

  Dim Msg as String

  Msg = “This is a really long string that lasts forever.“ & vbCrLf & vbCrLf & _

        “And this text will two lines below the previous one when shown in “ & _

        “Message box. Note that this paragraph will just wrap instead of “ & _

        “fixed formatting”.

  If <SomeTests> or _

     <SomeOtherTests> Then

    <DoSomethingHere>

  End If

  Call SubThatHasTheLongestArgumentListEver Arg1, Arg2, Arg3, _

                                            Arg4, Arg5

. . . 

3.4 Basic function declaration format

In Basic the functions are declared only once and because of that no separate declaration format is needed. Functions in external DLLs are declared with Declare statement and should always be copied from the original included files supplied by the author of DLL.

3.5 Basic source file format

All source code files must be formatted according the following example:

‘ --------------------------------------------------------------------------

‘ <Short_Name_For_Project> - <Long_name_for_project_or_component>

‘ --------------------------------------------------------------------------

‘

‘ One_line_file_description

‘ 

‘ Multiple_line_comment_that_can_be_used_to_further_describe_file_contents

‘

‘ Copyright © <Create_year> Wallac Oy, Wallac Confidential

‘ Microsoft Visual Basic 5.0

‘

‘ $Header: $

‘ Created: <Create_date> <Who_created>

‘

‘ --------------------------------------------------------------------------

‘ $Nokeywords: $

Option Explicit

‘ --------------------------------------------------------------------------

‘ Public data & events

‘ --------------------------------------------------------------------------

Public g_PublicVariable As Long

Event AssayIsNowReadyToBeServed(ByValAassayID as Long)

‘ --------------------------------------------------------------------------

‘ Private data

‘ --------------------------------------------------------------------------

Private m_ModuleLevelVariable as Long

‘ --------------------------------------------------------------------------

‘ Private functions

‘ --------------------------------------------------------------------------

Private Function MyFunction() As Long

‘

‘ Comment here

‘

  ‘ Code here

End Function

‘ --------------------------------------------------------------------------

‘ Event handlers

‘ --------------------------------------------------------------------------

Public sub cmdOK_Click()

‘

‘ Comment here

‘

  ‘ Code here

End Sub

‘ --------------------------------------------------------------------------

‘ Friend functions

‘ --------------------------------------------------------------------------

Friend Function MyFunction() As Long

‘

‘ Comment here

‘

  ‘ Code here

End Function

‘ --------------------------------------------------------------------------

‘ Public methods and property access functions

‘ --------------------------------------------------------------------------

Public Sub MySub(ByVal MyParameter As Long)

‘

‘ Comment here

‘


‘ Code here

End Sub

3.6 Visual Basic Templates

3.6.1 General information

Visual Basic provides a variety of templates for creating common application components. Instead of creating all the pieces from scratch, you can use existing templates or create your own.

You can open an existing template by selecting its icon in the Add Object dialog box when you create a new form, control, class or code module. Also projects can be made from templates.

Picture 1: Customized project templates

Wallac provides you with a set of customized templates that basically implement a skeleton code module, which you can use to build your application. They adhere to current Coding Standards and they include standard code blocks etc. They have placeholders that you should always replace with proper component names when building your component.

3.6.2 Wallac templates

In order to use Wallac's customized templates you should transfer them to your workstation from Visual Source Safe database. Visual Basic stores templates in a 'Template' subdirectory, which in turn contain subdirectories for projects, forms, classes and code modules etc. To place the Wallac templates into this directory structure, apply the following procedure.

1. Start Visual Source Safe.

2. Select folder 'Shared\WinWB\Template' .

3. Set the project path to point to your workstation VB template directory (most likely D:\Program Files\DevStudio\VBTemplate).

Do 'Get Latest Version' command and check 'Make writable' box when 'Get Template' dialog appears.











5. Use instead of standard templates when appropriate.

Note! 
A current list of available templates is included in this document in Appendix 3.

4. Code commenting conventions

4.1 Commenting in general

With Visual Basic, you may think that the code is always self-explanatory, but in most cases when doing more complicated applications, it is essential that the code is commented properly. In addition to the general code commenting guidelines, the following rules must always be followed when writing VB code:

Always put at least one line comment above a line or block which does something more than trivial arithmetic (anything more complicated than adding one to the loop counter is not trivial). Normally indent your comments with the code line and leave one space character between the comment starter, like this:

Sub GoHomeIfNotAWorkingDay()

‘

‘ Will go to home if we do not need to work during current day

‘

  ‘ Do we need to work now?

  If IsWeeked or IsHoliday Then

       ‘ Prepare to go home since this is not a working day



DoGoingHomePreaparations

    ShutComputerDown

    ‘ Drive from work to home

    LeaveBuilding

    GoToMyVectra

    DriveToHomeAsFastAsYouCan

  End If

End Sub

In case you temporarily comment out lines you do not want the program to perform, comment those lines and add TODO line(s), like this:

Sub GoHomeIfSaturday()

‘

‘ Will go to home if we do not need to work during current day

‘

  ‘ Do we need to work now?

  If IsWeeked or IsHoliday Then

    ‘ Prepare to go home since this is not a working day

    ‘ TODO: DoGoingHomePreaparations

    ‘ TODO: ShutComputerDown

    ‘ Drive from work to home

    LeaveBuilding

    GoToMyVectra

    DriveToHomeAsFastAsYouCan

  End If

End Sub

This way you don’t forget to do something about it later as it stands out from the code and you can grab the TODO string before you ship the code to customer to verify that all temporary tests have been removed from it.

Commenting your variables is not as straight-forward as the commenting blocks of code. In that case you have two options: either comment the variables in groups on the line preceding the first declaration in the group or comment individual declarations on the same line after the declaration. Like this:

Public Sub MySub()

  ‘ Variables to hold property data

  Dim LocalPropertyVar1 As Long

  Dim LocalPropertyVar2 As Long

  Dim LocalPropertyVar3 As Long

  Dim LocalPropertyVar4 As Long

  ‘ Temporary working variables

  Dim TempVar1 As Long ‘ The count of active users

  Dim TempVarWithLongName1 As Long ‘ Name of current user, if any

  Dim TempVar1 As Long ‘ Most likely user to crash Wallac server

End Sub

or like this:

‘ Structure to store a person

Type Person

  Name As String ‘ Holds the name

  Age As Byte ‘ Age in years

  Salary  as Currency ‘ MonthlySalary in FIMs

End Type

Normally, use the last one and reserve the first one only for variable/constant groups. The first comment form must be used when a) You comment the members of a structure or b) you have a collection of e.g. similar type of constants and you have short comments on each of them. 

5. Coding Style Conventions

5.1 Error Handling

5.1.1 Basic principles of error handling

Even in Visual Basic, your program is fully responsible of handling error situations. In case if no error trapping is done by the programmers, Visual Basic will trap the error itself, show the error message and terminate your program. This is not very nice in any kind of situation and it is most harmful in case of an ActiveX in-process component since it will crash also the client program. Since the error traps are functional only in case of linear execution (during one procedure and recursively during the procedures called from that procedure), it is not enough that you have one error trap in Main() and think that it will trap all errors in your program that are not trapped locally. During your event procedures, no trap is functional like in MyButton_Click unless you make one in that event yourself. That is why you should always have the time to create an error trap to all functions that have actions that might fail (all database actions, file i/o, DLL calls, OLE calls, opening of forms etc.). 

A realistic way to deal with errors effectively is to plan for them properly so that when they do occur: 

· The application does not crash.

· The error’s root cause (and thus cure) is relatively easy to determine.

· The error is as acceptable and as invisible to the user as possible. 

Hence, the basic rule is to have an error handler implemented in every procedure in Visual Basic. This rule can be exempted only in very small, one or two line, procedures, which don’t do any operations that should generate errors. 

An example of such a case is 'Property Let' statement, which only assigns a previously typed checked value from one variable to another

Public Property Let MyProperty(ByVal NewValue As String)

  m_MyValue = NewValue

End Property

Another rule is to log error information. If any user action is required to handle that error, record the corresponding action as well. A good error log provides invaluable information when trying to find those hard-to-catch anomalies.

5.1.2 Implementing error handlers

Handling errors properly in Visual Basic is also a good idea because of the alternative: Visual Basic’s default error handling rules are rather severe. Unhandled errors are reported, and then an End statement is executed. Keep in mind that an End stops your application dead—no form QueryUnload or Unload events, no class Terminate events, not much of anything, in fact.

Basically implementing an error handler is very simple. You use On Error statement to define and enable error trapping in your procedure. In that same statement you define a label to specify the place to jump to in case an error is trapped. 

Function GoAndDeleteFile(ByVal FileToDelete As String) As Boolean

'

' Comments

'

  On Error Goto ErrHandler

  ' Procedure code here

…

Error handling code itself is usually located on the last lines of the procedure so there has to be an Exit statement before it to prevent the program flow from proceeding normally. Error handling code starts from the label defined in On Error statement. In error handling code the Number property of Err object can be inspected to select what kind of errors are to handle locally and what to raise further. 

…

ExitProc:



Exit Sub/Function

ErrHandler:

  Select Case Err.Number

    Case SomethingThatWeCanHandle

      'TODO: Add local recovery

      Resume ExitProc

    Case Else

      Err.Source = Err.Source & "-Modulename.FunctionName"

      Err.Raise Err.Number, Err.Source, Err.Description

  End Select

End Sub/Function

If you do any local recovery you should always implement also a labeled exit of your error handler routine by using Resume statement. This clears all errors and thus makes it possible for your application to continue in the proper way.

In its simplest form your error handler may look like this:

…

ErrHandler:

  Err.Source = Err.Source & "-Modulename.FunctionName"

  Err.Raise Err.Number, Err.Source, Err.Description

End Sub/Function

Note!
You can use Source property of Err object to specify the procedure where the error was generated.

Raising Errors

Several different types of error handling can be used. Whatever way is chosen it should be implemented in such a manner that it makes it hard for others to ignore them and easy to handle properly.

Probably the best way to do this is to raise those errors that you decide not to handle locally. If you raise an error in your component it will be much harder for others to ignore that, at least if they have implemented a proper error handling as suggested. 

Another reason to use exceptions is that not using them can cause your code to become more difficult to follow—all those (un)necessary conditional tests to see that things have worked correctly. This kind of a scheme, in which you try some code and determine that it did not work by catching a thrown exception, is pretty close to “structured exception handling” as used in C++ and Microsoft Windows NT.

…

ErrHandler:

  Select Case Err.Number

    Case SomethingThatWeCanHandle

      'TODO: Add local recovery

      Resume ExitProc

    Case Else

      Err.Source = Err.Source & "-Modulename.FunctionName"

      Err.Raise Err.Number, Err.Source, Err.Description

  End Select

End Function

If the possible error will not affect anything and there is no need to notify anybody of that failure, Resume Next (but not ‘On Error Resume Next’) can be used:

Sub GoAndDeleteFileAndIgnoreAnyErrors(ByVal FileToDelete As String)

'

  On Error Goto ErrHandler

  Kill FileToDelete

  Exit Sub

ErrHandler:

  Resume Next

End Function

On Error Resume Next can be used only in situations when you want to turn off your normal error handler during a line or two and manually check for the possible error that occurred after those lines have been executed. If used during several lines, debugging of your program will get difficult.

Using return values 

This type of an approach is very useful for small functions, which don’t have to do a lot of cleanup themselves after the error. All actions due to an encounted error are done in the calling procedure.

Function GoAndDeleteFile(ByVal FileToDelete As String) As Boolean

  On Error Goto ErrHandler

  Kill FileToDelete

  GoAndDeleteFile = True

ExitProc:

  Exit Function

ErrHandler:

  GoAndDeleteFile = False

  Resume ExitProc

End Function

However this approach has some shortcomings which can sometimes have serious consequences. The most important of them is that sometimes programmers do ignore return values. 

Delayed error handling

The key to inline error handling is to test for an error immediately after each statement or function call. In this manner, you can design a handler that anticipates exactly the sort of error that might arise and resolve it accordingly. 

This approach does not require that an actual run-time error arise. This becomes useful when working with API and other DLL procedures, which do not raise Visual Basic exceptions. Instead, these procedures indicate an error condition, either in the return value, or in one of the arguments passed to the procedures; check the documentation for the procedure you are using to determine how these procedures indicate an error condition.

Note! 
You should  not use this type of error handling if it can be avoided.

…

' Enter error-critical section - delay the handling 

' of any possible resultant exception. 

On Error Resume Next 

Call VBA.FileSystem.GetAttr(sDriveAndFile) 

' Exit error-critical section. 

On Error GoTo err_DriveExists: 

' Check for those error that you want to trap

Select Case Err.Number

  Case PATH_NOT_FOUND: bDriveExists = False 

    ' Covers no error (error 0) and all other errors. 

    ' As far as we're concerned, these aren't 

    ' errors; e.g., "drive not ready" is OK. 

  Case Else bDriveExists = True 

End Select

…
5.1.2.1 Implementing error handlers in executable application

When implementing error handlers in application you usually have two options. You can either raise it to the calling procedure or handle it locally.

In those procedures that are called by other procedures you can always raise the error to the calling procedure after trying to deal with it locally.

When the procedure in question isn't called by any other procedure you have to handle that error locally. Of course, even then you may have a general procedure that logs the error and then presents it to User and, if possible, asks how to proceed.

5.1.2.2 Implementing error handler in components

When you implement error handlers in ActiveX components, keep in mind that the applications using the component have no way of trapping some of the errors, which makes it as vulnerable as your component is. If the application is an unattended one, serious problems may arise from your component not handling error situations properly.

As always, you should try to recover from errors locally if that is possible. If it is not possible, you should raise errors instead of using return values. 

Note!
Suggested reading: Advanced Visual Basic 5\On Error Goto Hell\Chapter1. 

6. Project organization

6.1 File and module naming

In Visual Basic, each module has the physical file name and also a name used internally inside the program. Naming of the files and modules must be done by following the guidelines:

	File name
	Module name
	Contents

	StartUp.bas
	StartUp
	Basic module containing Main()

	<MyModule>.bas
	<MyModule>
	Normal basic module

	<MyForm>.frm
	<frmMyForm>
	Normal form module

	<MyClass>.cls
	C<MyClass>
	Normal class module


NOTE! 
Text that is placed in brackets (<>) should be replaced within application specific term, all other strings are literals.

6.2 General IDE options

Following options MUST be set in Tools/Options:

Picture 2 - General VB IDE options

Require Variable Declaration:

Always keep ‘Require variable declaration’ check box checked under Tools / Options / Environment tab page. It adds ‘Option Explicit’ line in the beginning of your modules thus forcing explicit variable declaration. Without this line Visual Basic allows the use of variables not explicitly declared by the user.

Tab Width:

Set IDE to use 2 character tabs.

Auto Syntax Check:

Use this as you feel comfortable with. Visual Basic IDE will also mark the lines with different color in case they contain syntax errors.

6.3 Project options

6.3.1 General options

There are several names and options to set in the project options and in options when compiling your program into an .EXE or .DLL. This is what they should be:

Picture 3 - General project options

Startup Object: Sub Main
This provides more a robust way of starting your program than using a form as the startup module. Always use this setting if your application has more than one form.

Project Name

This name should be a descriptive name of the product / project. See “Project and Class naming” previously in this document for more information about project naming.

NOTE! 
Never create a project under the name "Wallac"!

Project description

This is a free description of the application that is shown, for example, in the object browser. It should contain a clear description about the component and its version number in textual form. Note that in case of an ActiveX component, this is the text that appears in the references dialog.

Upgrade ActiveX Controls

This feature should be turned off. Unintended upgrade can cause a lot of trouble if for some reason you are shipping an application, which is not synchronized with the controls that the customer already has. Naturally, this should never happen since all software releases should be bundled with appropriate controls.

6.3.2 Make options

There are several options to set in the Make options when compiling your program into an executable module. This is what they should be:

Picture 4 - Project make options

Auto Increment

This option should be turned off. Incrementing will be done manually when making a new release of your application. Always keep this version number the same as your project Label in Source Safe version control system.
Title

This is the title that will be shown in some of the task lists. Keep it short but do not use abbreviations. A good example would be ‘Microsoft Word’.

Icon

Always replace the default icon with your own (only in case of an exe).

Version Information

Ensure that your component has proper version information when it ships and ALWAYS increase the revision (build) number when you check in a new version of the component to the version control system. Also at least the following version information fields must be defined:


Company Name: 
<current company name>


Legal Copyright:
<current copyright text>

6.3.3 Compile options

There are several options to set in the Compile options group when compiling your program into an executable module. This is what they should be:

Picture 5 - Project compilation options

Compile to Native Code

Always compile to Native Code and select “Optimize for Small Code”. The Microsoft C2 compiler that is used by VB to generate the executable object code makes much less errors when optimizing for size and in almost all cases there will not be any difference in performance when compared to “Optimize for Fast Code”. Actually “Optimize for Small Code” can result in faster execution time because it can cause less disk swapping due to the smaller code size.

DLL Base address

This applies only to ActiveX components. It is good practice to allocate an address of its own for each component. If enough memory space is available, loading of your DLL will be faster.

6.3.4 Component options

The “Version Compatibility” is a VERY important option that needs to be set when you are making COM object servers with VB. 

Picture 6 - Project Component options

Initial development phase

Use “No Compatibility” during the first compilation.

Use “Project Compatibility” during the initial development. 

· First make the .EXE, .DLL or .OCX file

· Rename it to a .BIN file. This file should be in the same folder as the .VBP file.

· Select the “Project Compatibility” option

· In the “File Location” box, browse to the generated .BIN file. 

Normal development phase

When other users start using the component, change this setting to “Binary Compatibility”. This way the class id etc. will be kept the same with the subsequent compiles.

· Make the .EXE, .DLL or .OCX file

· Replace the version compatible component with the new compiled binary file. Note: the version compatible file name never changes.

· Add this .BIN file to the Visual Source Safe.

· Select “Binary Compatibility” option

· In the “File Location” box, browse to the generated .BIN file. 

Maintenance phase (binary compatible)

If you add methods or properties to the component, the binary compatibility is preserved. When the component with additions is given to other programmers or the component is frozen, it is important to update the binary compatible component so that it also contains those added interfaces, methods and properties. It is recommended to update the binary compatible component every time the actual binary file is checked in to the Visual Source Safe unless you are absolutely sure that no additions have been made. That can be checked by comparing the Type Library version number inside the component with a tool like OLE View.

· Make the new  .EXE, .DLL or .OCX file

· Check Out the version compatible file from the Visual Source Safe

· Replace the version compatible component with the new compiled binary file. Note: the version compatible file name never changes.

· Check In the version compatible file to the Visual Source Safe

If you accidentally change the interface of your COM server, compiler will warn you. You should press the cancel button and correct the code.

Maintenance phase (not binary compatible)

If you intentionally change the interface of your COM server, compiler will also warn you. You should press the cancel button. Don’t allow the VB IDE to modify the settings automatically. Proceed to one of the following instruction sets. Note: if your component has only one client and you compile the client right after you compiled the component, you can use the method 1 instead of the method 2. In this case you must ensure that the component and the client are always distributed together.

1. If the file is not yet sent to the customer and not yet officially frozen, you can proceed as follows: 

· Set the compatibility back to the “Project Compatibility” setting. 

· Make the new  .EXE, .DLL or .OCX file

· Check Out the version compatible file from the Visual Source Safe

· Replace the version compatible component with the new compiled binary file. Note: the version compatible file name never changes.

· Check In the version compatible file to the Visual Source Safe

· Set compatibility back to the “Binary Compatibility”

· Check that the “File Location” box remembers the correct .BIN file. 

· Inform other software developers, that the binary compatibility has been lost. They must unregister the old component, register the new one and recompile their projects.

2. If the file is already sent to the customer or is officially frozen, you can proceed as follows. This is especially important if this component is shared between several projects.

· Set the compatibility back to “No Compatible” setting. 

· Increment the component major version number.

· Change the project name to <old name> + <component major version number>. Example: MyApp is changed to MyApp2. If the project name already contains this major version number, replace it with the <component major version number>. Example: MyApp2 is changed to MyApp3.  If the project name contains a number which belongs to the component name, change the project name to <old name> + "_" + <component major version number>. Example: MLR4 is changed to MLR4_2. 
· Change the project description to old description + space + <component major version number>. Example: “My Application“ is changed to “My Application 2”.
· Make the new .EXE, .DLL or .OCX file. Change the file name to match the new project name. Example: MyApp.exe is changed to MyApp2.exe
· Check Out the version compatible file from the Visual Source Safe

· Replace the version compatible component with the new compiled binary file. Note: the version compatible file name never changes.

· Check In the version compatible file to the Visual Source Safe

· Set compatibility back to “Binary Compatibility”

· Check that the “File Location” box remembers the correct .BIN file. 

· Inform other software developers, that the binary compatibility has been lost. They can stay with the old version or modify their projects to use this new version.

NOTE 1 
Never change COM interface that has been shipped to customers and is being used by others than the product itself! COM interfaces can not change. You can only add new items to the existing object server. Nothing can be changed or removed.

NOTE 2 
If you need to break the compatibility, make a clean break: Change the project name, the file name and all GUIDS .This ensures that existing applications can continue to work with the old component while new versions can use the new component.

NOTE 3
There is a very thorough article about 'Building, Versioning and Maintaining Visual Basic Components' that can be found in the MSDN Library.

7. Localization issues in VB

7.1 General principles

All applications should be designed and programmed in such a manner that localization should be a relatively easy and straightforward task. Localization involves creating a functional core code base and a generic feature design that can serve as the basis for all language editions of a product.

There is an ongoing project in Wallac that will touch this subject in depth and it should finally produce a new guideline concerning localization issues. In the meantime the instructions and suggestions presented in this chapter should be applied to current and starting projects in order to minimize localization efforts.

7.2 Things to consider

The most effective process for creating localized products takes international considerations into account at the beginning of the product cycle and throughout development, and expedites the shipping of multiple language editions.

Different language editions of Windows can be grouped in categories with similar development issues. Once you have created a program for one language in a category, the development effort involved in creating editions of your program for other languages in the same category is minimal.
Defaults that change from locale to locale include spoken languages; written scripts; sorting orders; keyboard layouts; input methods; common paper sizes; and date, time, number, and currency formats.
7.3 Some issues concerning application design and coding

The following specifications are by no means complete but they provide some information about things that should be considered when programming applications in VB.

7.3.1 Supported languages

It should be clearly defined what languages and character sets each product supports. Consider also whether right-to-left writing is supported.

The application should install all available languages or the users’ explicit choice at the time of the installation. Application supports one language at a time, which is specified at the starting moment either by registry settings if specified or by local settings. In case of missing settings or currently unsupported local language application always defaults to US English.

7.3.2 Interface design issues

Remember to reserve enough space for translated strings. This means naturally horizontal direction but surprisingly also vertical direction. Non Latin character sets require about 30% more space in vertical direction.

Furthermore, you are not advised to use text in bitmaps and icons since they require additional task and tools to localize. It is also important to note that the same symbols can have different meanings in other cultures, so be careful to choose your signs and ask local experts to verify the correctness of your choice.

7.3.3 Coding issues

The basic rule is to use resource files to store strings and other resources. Doing so makes your programs smaller and faster to load and make localization process a much easier task. In case of an application that has a database, that can also be used for string storage.

Do not use hard coded strings in your application.

Do not create strings visible to user by concatenating several strings together. In different languages the structure of the same sentence might be reversed or otherwise different. Use placeholders instead.

Remember that Visual Basic itself is not Unicode aware; instead, you need to set the font of each control showing non-western characters to the correct character set. Many of the 3rd party components are Unicode aware and need no specific coding in this respect.

Never rely on date, time or number formats as the user can change them freely in Control Panel. Keep in mind how these conversion routines behave in Visual Basic:

CStr: uses regional settings to convert any variant to string

CDbl / CSng: uses regional settings to convert a string into a floating point number

Str: converts a number to string, always using period (.) as the decimal separator

Val: Converts a string to number, always using period (.) as the decimal separator

8. Appendix 1 - Control Naming

Control name prefixes for the most common used controls are shown in the table below:

	Object
	Prefix
	Example

	<AnyControlNotInThisList>
	ctl
	CtlPacketMonitor

	Check box
	chk
	ChkReadOnly

	Combo box
	cbo
	CboEnglish

	Data-bound combo box
	dbc
	dbcEnglish

	Command button
	cmd
	cmdCancel

	Data
	dat
	datBiblio

	Directory list box
	dir
	dirSource

	Drive list box
	drv
	drvTarget

	File list box
	fil
	filSource

	Frame
	fra
	fraLanguage

	Data-bound grid
	dbg
	dbgPrices

	Horizontal scroll bar
	hsb
	hsbVolume

	Image 
	img
	imgIcon

	ImageList
	iml
	imlNodeIcons

	Label
	lbl
	lblHelpMessage

	Line 
	lin
	linVertical

	List box
	lst
	lstPolicyCodes

	Data-bound list box
	dbl
	dblPolicyCode

	ListView
	lvw
	lvwFileList

	OLE container
	ole
	oleObject1

	Option button
	opt
	optFrench

	Picture box
	pic
	picDiskSpace

	ProgressBar
	pbr
	pbrPercentCopied

	RichTextBox
	rtb
	rtbFormattedText

	Shape
	shp
	shpCircle

	Slider
	sld
	sldPriority

	StatusBar
	sbr
	sbrMain

	TabStrip
	tab
	tabPropertyPages

	Text box
	txt
	txtGetText

	Timer
	tmr
	tmrAlarm

	ToolBar
	tbr
	tbrMain

	TreeView
	tvw
	tvwDirectoryTree

	Vertical scroll bar
	vsb
	vsbRate


	Menu
	mnu
	mnuFileOpen

	Form
	Frm
	frmFileOpen


	Grid
	Grd
	grdPrices

	Dynazip zip control
	Dnz
	dnzZipper

	Dynazip unzip control
	Duz
	duzUnzipper

	Graph Control (GSW)
	Gra
	graStandardCurve

	Chart (Olectra)
	Cht
	chtStandardCurve

	SSPanel
	Pnl
	pnlOptionGroup


9. Appendix 2 - Common VB code libraries 

These Visual Basic code library files can be found from our Visual Source Safe database. 

	Name
	Location
	Description

	WUtil.bas
	VSS
	Contain general useful procedures for e.g. string handling, finding current Windows user name… 

	
	
	


10. Appendix 3 - Common Wallac templates

	Name
	Type
	Location
	Description

	Wallac Standard EXE project
	Project
	VSS
	Template for EXE type project

	Wallac ActiveX DLLproject
	Project
	
	Template for ActiveX DLL type project

	Wallac ActiveX PP DLL project
	Project
	
	Template for ActiveX Persistence Provider DLL type project

	Wallac Standard Module
	Module
	VSS
	Standard code module for 

	Wallac Standard StartUp
	Module
	VSS
	Standard StartUp code module for exe type project

	Wallac Standard ActiveX StartUp
	Module
	VSS
	Standard StartUp code module for ActiveX Dll type project

	Wallac Standard PP ActiveX StartUp
	Module
	VSS
	Standard StartUp code module for Active X  Persistence Provider type project

	Wallac Standard Form
	Form
	VSS
	Standard form module

	Wallac Standard Class
	Class
	VSS
	Standard Class module

	Wallac Persistence Provider Class
	Class
	VSS
	Standard template for connecting persistence provider project to WPersistence object


11. Appendix 4 – Code review checklist

11.1 General

1. All the files the project needs must be in SourceSafe, including compatible servers. Test by doing ‘get’ to a clean directory, preferably on somebody else’s computer. Then open the project in VB IDE.

2. Project Title, Description and Name are defined. Description of COM servers starts with word ‘Wallac’.

3. Build number of the output file is incremented in each build which is checked in. Major or minor version numbers are incremented only when significant changes are made.

4. List of dependencies is written listing ALL the components required by the program.

5. Test installation and the program itself in a clean PC available in the testing laboratory.

11.2 Source code

1. The standard comment blocks are used and all of their placeholders are replaced.

2. There are no commented sections containing obsolete code. SourceSafe is used for tracking changes.

3. All members (constants, variables, events, methods, etc.) are in their own sections. Event handlers are in a separate section from other private procedures.

4. The scope of classes and class members is only as public as needed.

5. Public members of COM interfaces are commented by using WProcFormatter.

6. ByVal or ByRef is always declared explicitly for each parameter and ByRef is only used for a reason.

7. Constants are used instead of actual values when referring to items in a list, control array, etc.

8. All event handlers have an error handler, which handles the error (does not raise it to the caller).

9. All other procedures raise the error to the caller unless there is a reason to handle it locally.

10. There is only one ‘On Error’ statement in each procedure.

11. Methods from WUTIL.BAS and other common modules/components are used instead of own ones.

12. Forms, classes and usercontrols have one method to set the initial state instead of setting individual public properties. With forms this method also opens the form and returns information needed by the caller.

13. Database connection string comes from a UDL file whenever possible.

11.3 Appearance

1. Exe files have some other icon than the standard form icon, usually the same one as the icon of the main form.

2. Main form is shown modeless and ShowInTaskBar is set to True if normal Taskbar behavior is expected.

3. Forms are opened to the correct position of the screen (usually CenterOwner).

4. Forms have correct Borderstyle. If form is sizable, its contents is moved and/or resized with the form.

5. Forms have Maxbutton, Minbutton, and Controlbox set appropriately. Built-in VB icons are not shown.

6. Tab order is correct and accelerator keys are used where appropriate.

7. Ok/cancel/apply etc. buttons are in the correct order and ‘Default’ and ‘Cancel’ properties are set correctly. 

8. Controls are sized and aligned correctly. Pay special attention to labels in front of text boxes.

9. Style of Comboboxes and LabelEdit property of Listview and Treeview controls is set correctly.

10. One option of an option button group is selected by default, usually it should be the first one.

11. System colors are used instead of direct RGB values. Check by changing your windows color scheme.

12. Lists are sorted when appropriate, listviews sort ascending/descending when clicking the column header.

13. Ellipsis (…) is used in captions when they should (see Windows Interface Guidelines).

14. Only valid characters and a valid amount of them can be entered into controls accepting input.

15. Date, currency etc. strings visible to the user are formatted using the current regional settings.

12. Document change history

	Rev.
	Approval date
	Author

	Change Order

	1
	23.5.1996
	Jarkko Sakki
	Initial version
	

	2
	21.1.1997
	Juha Korsimo
	Revised version
	

	3
	1.9.1998
	Mikko Räsänen
	Template updated and contents revised
	

	4
	21.03.2003
	Tom Sarasniemi

	Juha Korsimo

